pkgname=golded-plus-utf
pkgver=r1748.4ef277e
_ncurses_pkgver=6.2
_ncurses="ncurses"
pkgrel=1
pkgdesc="golded-plus Fidonet Mail Reader/Editor"
arch=('i686' 'x86_64' 'aarch64')
url="http://bbconf.sourceforge.net/"
license=('GPL2')
source=(
    "${pkgname}::git+https://github.com/evs38/golded-plus.git"
    "golded"
    "mygolded.h"
)
makedepends=('git' 'gcc' 'make' 'glibc' 'groff')
# depends=('')
provides=('golded-plus')
conflicts=('golded-plus-git')

build() {
    pushd "${pkgname}"
    mkdir build
    cd build
    cmake -DCMAKE_BUILD_TYPE:STRING=Release \
 -DWIDE_NCURSES:INTEGER=1 ..
    cmake --build . -j 4
#    make WIDE_NCURSES=0 USE_NCURSES=1 KOI8=1 -j$(nproc)
    cd ..
    pushd docs
    make tokentpl.txt
    make tokencfg.txt
    popd
    make docs
    popd
}

prepare() {
    cd "${pkgname}"
    cp "../mygolded.h" "golded3/mygolded.h"
#    patch -p1 -i "../ncurses.patch"
    iconv -c -f cp866 -t utf8 docs/rusfaq.txt |  sed 2s/cp866/utf-8/ >docs/rusfaq.utf8
    iconv -c -f cp866 -t utf8 docs/notework.rus |  sed 2s/cp866/utf-8/ >docs/notework_rus.utf8
    iconv -c -f cp866 -t koi8-r docs/rusfaq.txt |  sed 2s/cp866/koi8/ >docs/rusfaq.koi8
    iconv -c -f cp866 -t koi8-r docs/notework.rus |  sed 2s/cp866/koi8/ >docs/notework_rus.koi8
    pushd cfgs/config
    for i in *.ru?; do
      iconv -c -f cp866 -t koi8-r ${i} |  sed 2s/cp866/koi8/ > ${i}.koi8
      iconv -c -f cp866 -t utf-8 ${i} |  sed 2s/cp866/utf-8/ > ${i}.utf8 
    done
    iconv -c -f cp866 -t koi8-r aliasru.cfg |  sed 2s/cp866/koi8/ > aliasru.koi8
    iconv -c -f cp866 -t utf-8 aliasru.cfg |  sed 2s/cp866/utf-8/ > aliasru.utf8 
    popd
    pushd cfgs/template
    iconv -c -f cp866 -t koi8-r rusCP866.tpl |  sed 2s/cp866/koi8/ > rusKOI8.tpl
    iconv -c -f cp866 -t utf-8 rusCP866.tpl |  sed 2s/cp866/utf-8/ > rusUTF8.tpl
    popd
}

pkgver() {
    cd "$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    cd ..
}

package() {
    pushd "${pkgname}"
    mkdir -m 755 -p "${pkgdir}/usr/share/goldedplus"/{docs,charset,colorset,config,template}
    install -d "${pkgdir}/usr/bin"
    install -m 755 "${srcdir}/${pkgname}/build/rddt/rddt" "${pkgdir}/usr/bin/rddt"
    install -m 755 "${srcdir}/${pkgname}/build/goldnode/goldnode" "${pkgdir}/usr/bin/goldnode"
    install -m 755 "${srcdir}/${pkgname}/build/golded3/golded" "${pkgdir}/usr/bin/gedlnx"
    install -m 755 "${srcdir}/golded" "${pkgdir}/usr/bin/golded"
    patchelf --set-rpath /usr/lib/ncurses-golded/lib "${pkgdir}/usr/bin/gedlnx"
    install -d "${pkgdir}/usr/man/man1"
    install -m 644 docs/*.1 "${pkgdir}/usr/man/man1/"
    install -m 644 etc/gecolor.conf "${pkgdir}/usr/share/goldedplus/colorset/gedcolor.cfg"
    install -m 644 cfgs/config/* "${pkgdir}/usr/share/goldedplus/config"
    install -m 644 cfgs/template/* "${pkgdir}/usr/share/goldedplus/template"
    install -m 644 cfgs/charset/* "${pkgdir}/usr/share/goldedplus/charset"
    install -m 644 cfgs/colorset/* "${pkgdir}/usr/share/goldedplus/colorset"
    install -m 644 docs/*.utf8 "${pkgdir}/usr/share/goldedplus/docs"
    install -m 644 docs/*.koi8 "${pkgdir}/usr/share/goldedplus/docs"
    install -m 644 docs/{tips,linux,notework,tokencfg,tokentpl}.txt "${pkgdir}/usr/share/goldedplus/docs"
}

sha256sums=('SKIP'
            '29633876d92ed516558919e5d4c5093d48e5c8216ffbaaaa83581d3f8573e551'
            '75105e2a6b0dd763d53a45b09c4b93daeab9ab1888ecba624a0f9b4099174e3e')